feat(revamp): add zsh and neovim configs, add an install script and a dependencies list

2026-04-20 12:17:46 +02:00
parent f9f5b1e184
commit 27b1db55df
227 changed files with 13985 additions and 0 deletions
@@ -0,0 +1,47 @@
+# GNU Screen
+
+Defines [GNU Screen][1] aliases and provides for auto launching it at start-up.
+
+## Settings
+
+### Auto-Start
+
+Starts a GNU Screen session automatically when Zsh is launched.
+
+To enable this feature when launching Zsh in a local terminal, add the following
+line to _`${ZDOTDIR:-$HOME}/.zpreztorc`_:
+
+```sh
+zstyle ':prezto:module:screen:auto-start' local 'yes'
+```
+
+To enable this feature when launching Zsh in a SSH connection, add the following
+line to _`${ZDOTDIR:-$HOME}/.zpreztorc`_:
+
+```sh
+zstyle ':prezto:module:screen:auto-start' remote 'yes'
+```
+
+## Aliases
+
+Aliases are enabled by default. To disable them, add the following to
+_`${ZDOTDIR:-$HOME}/.zpreztorc`_.
+
+```sh
+zstyle ':prezto:module:screen:alias' skip 'yes'
+```
+
+- `scr` is short for `screen`.
+- `scrl` lists sessions/socket directory.
+- `scrn` starts a new session.
+- `scrr` attaches to a session if one exists or start a new one.
+
+## Authors
+
+_The authors of this module should be contacted via the [issue tracker][2]._
+
+- [Sorin Ionescu](https://github.com/sorin-ionescu)
+- [Georges Discry](https://github.com/gdiscry)
+
+[1]: https://www.gnu.org/software/screen/
+[2]: https://github.com/sorin-ionescu/prezto/issues
@@ -0,0 +1,44 @@
+#
+# Defines GNU Screen aliases and provides for auto launching it at start-up.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#   Georges Discry <georges@discry.be>
+#
+
+# Return if requirements are not found.
+if (( ! $+commands[screen] )); then
+  return 1
+fi
+
+#
+# Auto Start
+#
+
+if [[ -z "$STY" && -z "$EMACS" && -z "$VIM" ]] && ( \
+  ( [[ -n "$SSH_TTY" ]] && zstyle -t ':prezto:module:screen:auto-start' remote ) ||
+  ( [[ -z "$SSH_TTY" ]] && zstyle -t ':prezto:module:screen:auto-start' local ) \
+); then
+  session="$(
+    screen -list 2> /dev/null \
+      | sed '1d;$d' \
+      | awk '!/Dead/ {print $1}' \
+      | head -1)"
+
+  if [[ -n "$session" ]]; then
+    exec screen -x "$session"
+  else
+    exec screen -a -A -U -D -R -m "$SHELL" -l
+  fi
+fi
+
+#
+# Aliases
+#
+
+if ! zstyle -t ':prezto:module:screen:alias' skip; then
+  alias scr='screen'
+  alias scrl='screen -list'
+  alias scrn='screen -U -S'
+  alias scrr='screen -a -A -U -D -R'
+fi