feat(revamp): add zsh and neovim configs, add an install script and a dependencies list

config/zsh/.zprezto/modules/ruby/functions/ruby-app-root

@@ -0,0 +1,22 @@
+#
+# Displays the path to the Ruby application root directory.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+# function ruby-app-root {
+
+local root_dir="$PWD"
+
+while [[ "$root_dir" != '/' ]]; do
+  if [[ -f "$root_dir/Gemfile" ]]; then
+    print "$root_dir"
+    break
+  fi
+  root_dir="$root_dir:h"
+done
+
+return 1
+
+# }

config/zsh/.zprezto/modules/ruby/functions/ruby-info

@@ -0,0 +1,38 @@
+#
+# Exposes information about the Ruby environment via the $ruby_info associative
+# array.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+# function ruby-info {
+
+local version
+local version_format
+local version_formatted
+
+# Clean up previous $ruby_info.
+unset ruby_info
+typeset -gA ruby_info
+
+# Grab formatting for anything we might have to do
+zstyle -s ':prezto:module:ruby:info:version' format 'version_format'
+
+if [[ -n "$version_format" ]]; then
+  if (( $+commands[rvm-prompt] )); then
+    version="$(rvm-prompt)"
+  elif (( $+commands[rbenv] )); then
+    version="$(rbenv version-name)"
+  elif (( $+commands[ruby] )); then
+    version="${${$(ruby --version)[(w)1,(w)2]}/ /-}"
+  fi
+
+  # Format version.
+  if [[ -n "$version" && "$version" != "system" ]]; then
+    zformat -f version_formatted "$version_format" "v:$version"
+    ruby_info[version]="$version_formatted"
+  fi
+fi
+
+# }