feat(revamp): add zsh and neovim configs, add an install script and a dependencies list

2026-04-20 12:17:46 +02:00
parent f9f5b1e184
commit 27b1db55df
227 changed files with 13985 additions and 0 deletions
@@ -0,0 +1,26 @@
+# Rsync
+
+Defines [rsync][1] aliases.
+
+macOS users are encouraged to use _rsync_ from [Homebrew][2] or [MacPorts][3],
+which has additional enhancements including patches from [Bombich][4].
+
+## Aliases
+
+- `rsync-copy` copies files and directories from _source_ to _destination_.
+- `rsync-move` moves files and directories from _source_ to _destination_.
+- `rsync-update` updates files and directories on _destination_.
+- `rsync-synchronize` synchronizes files and directories between _source_ and
+  _destination_.
+
+## Authors
+
+_The authors of this module should be contacted via the [issue tracker][5]._
+
+- [Sorin Ionescu](https://github.com/sorin-ionescu)
+
+[1]: https://rsync.samba.org
+[2]: https://github.com/Homebrew/homebrew-core
+[3]: https://ports.macports.org/port/rsync
+[4]: https://bombich.com/kb/ccc5/credits#rsync
+[5]: https://github.com/sorin-ionescu/prezto/issues
@@ -0,0 +1,43 @@
+#
+# Defines Rsync aliases.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+# Return if requirements are not found.
+if (( ! $+commands[rsync] )); then
+  return 1
+fi
+
+# Load dependencies.
+pmodload 'helper'
+
+#
+# Aliases
+#
+
+_rsync_cmd='rsync --verbose --progress --human-readable --compress --archive \
+  --hard-links --one-file-system'
+
+autoload -Uz is-at-least
+if is-at-least 3.1 ${"$(rsync --version 2>&1)"[(w)3]}; then
+
+  # ACL and extended attributes support
+  if grep -q 'xattrs' <(rsync --help 2>&1); then
+    _rsync_cmd="${_rsync_cmd} --acls --xattrs"
+  fi
+
+  # macOS Enhancements
+  # https://bombich.com/kb/ccc5/credits
+  if is-darwin && grep -q 'file-flags' <(rsync --help 2>&1); then
+    _rsync_cmd="${_rsync_cmd} --crtimes --fileflags --force-change"
+  fi
+fi
+
+alias rsync-copy="${_rsync_cmd}"
+alias rsync-move="${_rsync_cmd} --remove-source-files"
+alias rsync-update="${_rsync_cmd} --update"
+alias rsync-synchronize="${_rsync_cmd} --update --delete"
+
+unset _rsync_cmd