feat(revamp): add zsh and neovim configs, add an install script and a dependencies list

2026-04-20 12:17:46 +02:00
parent f9f5b1e184
commit 27b1db55df
227 changed files with 13985 additions and 0 deletions
@@ -0,0 +1,15 @@
+#compdef grunt
+#autoload
+
+#
+# Grunt completion, delegating to grunt to do all the completion work.
+#
+# Authors:
+#   Indrajit Raychaudhuri <irc@indrajit.com>
+#
+
+if (( $+commands[grunt] )); then
+  eval "$(grunt --completion=zsh)"
+
+  _grunt_completion "$@"
+fi
@@ -0,0 +1,15 @@
+#compdef gulp
+#autoload
+
+#
+# Gulp completion, delegating to gulp to do all the completion work.
+#
+# Authors:
+#   Indrajit Raychaudhuri <irc@indrajit.com>
+#
+
+if (( $+commands[gulp] )); then
+  eval "$(gulp --completion=zsh)"
+
+  _gulp_completion "$@"
+fi
@@ -0,0 +1,18 @@
+#
+# Opens the Node.js online API documentation in the default browser.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+# function node-doc {
+
+if [[ -z "$BROWSER" ]]; then
+  print "$0: no web browser defined" >&2
+  return 1
+fi
+
+# TODO: Make the sections easier to use.
+"$BROWSER" "https://nodejs.org/docs/${$(node --version 2> /dev/null)/%-*}/api/all.html#${1}"
+
+# }
@@ -0,0 +1,32 @@
+#
+# Exposes information about the Node.js environment via the $node_info
+# associative array.
+#
+# Authors:
+#   Zeh Rizzatti <zehrizzatti@gmail.com>
+#
+
+# function node-info {
+
+local version
+local version_format
+local version_formatted
+
+unset node_info
+typeset -gA node_info
+
+if (( $+commands[nodenv] )); then
+  version="${${$(nodenv version)#v}[(w)0]}"
+elif (( $+functions[nvm_version] )); then
+  version="${$(nvm_version)#v}"
+elif (( $+commands[node] )) ; then
+  version="${$(node -v)#v}"
+fi
+
+if [[ "$version" != (none|system) ]]; then
+  zstyle -s ':prezto:module:node:info:version' format 'version_format'
+  zformat -f version_formatted "$version_format" "v:$version"
+  node_info[version]="$version_formatted"
+fi
+
+# }