feat(revamp): add zsh and neovim configs, add an install script and a dependencies list

config/zsh/.zprezto/modules/helper/README.md

@@ -0,0 +1,26 @@
+# Helper
+
+Provides helper functions for developing modules.
+
+## Functions
+
+- `add-zsh-trap` adds a function name to a list to be called when a trap is
+  triggered.
+- `is-autoloadable` checks if a file can be autoloaded by trying to load it in
+  a subshell.
+- `is-callable` checks if a name is a command, function, or alias.
+- `is-true` checks a boolean variable for "true".
+- `coalesce` prints the first non-empty string in the arguments array.
+- `is-darwin` checks if running on macOS Darwin.
+- `is-linux` checks if running on Linux.
+- `is-bsd` checks if running on BSD.
+- `is-cygwin` checks if running on Cygwin (Windows).
+- `is-termux` checks if running on Termux (Android).
+
+## Authors
+
+_The authors of this module should be contacted via the [issue tracker][1]._
+
+- [Sorin Ionescu](https://github.com/sorin-ionescu)
+
+[1]: https://github.com/sorin-ionescu/prezto/issues

config/zsh/.zprezto/modules/helper/functions/add-zsh-trap

@@ -0,0 +1,41 @@
+#
+# Provides for trapping UNIX signals and calling callback functions when a trap
+# is triggered.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+# Adds a function name to a list to be called when a trap is triggered.
+function add-zsh-trap {
+  if (( $# < 2 )); then
+    print "usage: $0 type function" >&2
+    return 1
+  fi
+
+  if [[ -z "$signals[(r)$1]" ]]; then
+    print "$0: unknown signal: $1" >&2
+    return 1
+  fi
+
+  local trap_functions="TRAP${1}_FUNCTIONS"
+  if (( ! ${(P)+trap_functions} )); then
+    typeset -gaU "$trap_functions"
+  fi
+  eval "$trap_functions+="$2""
+
+  if (( ! $+functions[TRAP${1}] )); then
+    eval "
+      function TRAP${1} {
+        for trap_function in \"\$TRAP${1}_FUNCTIONS[@]\"; do
+          if (( \$+functions[\$trap_function] )); then
+            \"\$trap_function\" \"\$1\"
+          fi
+        done
+        return \$(( 128 + \$1 ))
+      }
+    "
+  fi
+}
+
+add-zsh-trap "$@"

config/zsh/.zprezto/modules/helper/functions/escape-eval

@@ -0,0 +1,13 @@
+#
+# Escapes a string for safe use in ${(e)...} parameter expansion.
+#
+# Authors:
+#   Trey Keown <trey@crystalpeaksecurity.com>
+#
+
+# function escape-eval {
+
+setopt LOCAL_OPTIONS EXTENDED_GLOB
+print -r -- "${1//(#m)[\\\$\`]/\\$MATCH}"
+
+# }

config/zsh/.zprezto/modules/helper/init.zsh

@@ -0,0 +1,56 @@
+#
+# Defines helper functions.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+# Checks if a file can be autoloaded by trying to load it in a subshell.
+function is-autoloadable {
+  ( unfunction $1 ; autoload -U +X $1 ) &> /dev/null
+}
+
+# Checks if a name is a command, function, or alias.
+function is-callable {
+  (( $+commands[$1] || $+functions[$1] || $+aliases[$1] || $+builtins[$1] ))
+}
+
+# Checks a boolean variable for "true".
+# Case insensitive: "1", "y", "yes", "t", "true", "o", and "on".
+function is-true {
+  [[ -n "$1" && "$1" == (1|[Yy]([Ee][Ss]|)|[Tt]([Rr][Uu][Ee]|)|[Oo]([Nn]|)) ]]
+}
+
+# Prints the first non-empty string in the arguments array.
+function coalesce {
+  for arg in $argv; do
+    print "$arg"
+    return 0
+  done
+  return 1
+}
+
+# Checks if running on macOS Darwin.
+function is-darwin {
+  [[ "$OSTYPE" == darwin* ]]
+}
+
+# Checks if running on Linux.
+function is-linux {
+  [[ "$OSTYPE" == linux* ]]
+}
+
+# Checks if running on BSD.
+function is-bsd {
+  [[ "$OSTYPE" == *bsd* ]]
+}
+
+# Checks if running on Cygwin (Windows).
+function is-cygwin {
+  [[ "$OSTYPE" == cygwin* ]]
+}
+
+# Checks if running on termux (Android).
+function is-termux {
+  [[ "$OSTYPE" == linux-android ]]
+}